# STDLOGIN
#       A more or less 'standard' login file that should be located
#       in $STD/.stdlogin, rw-r--r-- root/sys, and sourced from the
#       top of all user's .login files:
#
#               set STD=/usr/local/adm
#               source $STD/.stdlogin
#
#                                               erco@3dsite.com

# STANDARD TERMINAL SETUP
set noglob; eval `tset -s -Q`; unset noglob
stty erase ^H kill ^U intr ^C echoe ixon ixany
if ( $?TERM == 0 ) setenv TERM xterm

echo "TERM is $TERM"

# PLATFORM DEPENDENT SETTINGS
switch ( "$PLATFORM" )

    case 'IRIX*':
        if ( ! $?DISPLAY ) then
            if ( $?REMOTEHOST ) then
                # REMOTE X TERMINAL
                setenv DISPLAY "${REMOTEHOST}:0"
            else
                # LOCAL X TERMINAL
                setenv DISPLAY :0
            endif
        endif
        eval `resize`           # for dialup xterms
        breaksw

    case 'Linux*':
        if ( ! $?DISPLAY ) setenv DISPLAY :0
# DONT DO THIS - TELEVIDEO PUKES IF YOU RUN resize(1)
#       if ( "$TERM" != "tvi950") then
#           echo RESIZE..
#           eval `resize`
#       endif

        stty tab3               # so 'cat file_with_tabs' works in sgi rlogin
        breaksw

    case 'SunOS*':
        eval `resize`           # for dialup xterms
        breaksw
endsw